FlexibleSUSY is hosted by Hepforge, IPPP Durham
NUHMSSMNoFVHimalaya

NUHMSSMNoFVHimalaya

NUHMSSMNoFVHimalaya (non-universal Higgs MSSM without flavour violation + Himalaya) is an implementation of the MSSM without flavour violation. The Himalaya library [arXiv:1708.05720] is linked to this model to include 3-loop corrections of $O(\alpha_t\alpha_s^2)$ [arXiv:0803.0672, arXiv:1005.5709] to the light CP-even Higgs pole mass. The setup of NUHMSSMNoFVHimalaya is shown in the following figure.

NUHMSSMNoFVHimalaya_tower.svg

Building the NUHMSSMNoFVHimalaya

In order to use the 3-loop contributions to the light CP-even Higgs mass from the Himalaya library, the NUHMSSMNoFVHimalaya must be configured with the `--enable-himalaya` flag:

./createmodel --name=NUHMSSMNoFVHimalaya ./configure --with-models=NUHMSSMNoFVHimalaya \ --enable-himalaya \ --with-himalaya-incdir=${HIMALAYA_DIR}/source/include \ --with-himalaya-libdir=${HIMALAYA_DIR}/build make

In the above example `HIMALAYA_DIR` is the path to the Himalaya directory.

Input parameters

NUHMSSMNoFVHimalaya takes the following physics parameters as input:

Parameter | Description | SLHA block/field | Mathematica symbol --------------------------------------------|----------------------------------------------------------------------------|------------------|-------------------- $Q_{\text{in}}$ | input scale | `EXTPAR[0]` | `Qin` $M_1(M_\text{SUSY})$ | Bino mass | `EXTPAR[1]` | `M1` $M_2(M_\text{SUSY})$ | Wino mass | `EXTPAR[2]` | `M2` $M_3(M_\text{SUSY})$ | Gluino mass | `EXTPAR[3]` | `M3` $A_t(M_\text{SUSY})$ | trililear stop coupling | `EXTPAR[11]` | `AtIN` $A_b(M_\text{SUSY})$ | trililear sbottom coupling | `EXTPAR[12]` | `AbIN` $A_\tau(M_\text{SUSY})$ | trililear stau coupling | `EXTPAR[13]` | `AtauIN` $A_c(M_\text{SUSY})$ | trililear scharm coupling | `EXTPAR[14]` | `AcIN` $A_s(M_\text{SUSY})$ | trililear sstrange coupling | `EXTPAR[15]` | `AsIN` $A_\mu(M_\text{SUSY})$ | trililear smuon coupling | `EXTPAR[16]` | `AmuonIN` $A_u(M_\text{SUSY})$ | trililear sup coupling | `EXTPAR[17]` | `AuIN` $A_d(M_\text{SUSY})$ | trililear sdown coupling | `EXTPAR[18]` | `AdIN` $A_e(M_\text{SUSY})$ | trililear selectron coupling | `EXTPAR[19]` | `AeIN` $\mu(M_\text{SUSY})$ | $\mu$-parameter | `EXTPAR[23]` | `MuIN` $m_A^2(M_\text{SUSY})$ | running CP-odd Higgs mass | `EXTPAR[24]` | `mA2IN` $(m_{\tilde{l}}^2)_{11}(M_\text{SUSY})$ | soft-breaking 1st generation left-handed slepton mass parameters | `EXTPAR[31]` | `ml11IN` $(m_{\tilde{l}}^2)_{22}(M_\text{SUSY})$ | soft-breaking 2nd generation left-handed slepton mass parameters | `EXTPAR[32]` | `ml22IN` $(m_{\tilde{l}}^2)_{33}(M_\text{SUSY})$ | soft-breaking 3rd generation left-handed slepton mass parameters | `EXTPAR[33]` | `ml33IN` $(m_{\tilde{e}}^2)_{11}(M_\text{SUSY})$ | soft-breaking 1st generation right-handed slepton mass parameters | `EXTPAR[34]` | `me11IN` $(m_{\tilde{e}}^2)_{22}(M_\text{SUSY})$ | soft-breaking 2nd generation right-handed slepton mass parameters | `EXTPAR[35]` | `me22IN` $(m_{\tilde{e}}^2)_{33}(M_\text{SUSY})$ | soft-breaking 3rd generation right-handed slepton mass parameters | `EXTPAR[36]` | `me33IN` $(m_{\tilde{q}}^2)_{11}(M_\text{SUSY})$ | soft-breaking 1st generation left-handed squark mass parameters | `EXTPAR[41]` | `mq11IN` $(m_{\tilde{q}}^2)_{22}(M_\text{SUSY})$ | soft-breaking 2nd generation left-handed squark mass parameters | `EXTPAR[42]` | `mq22IN` $(m_{\tilde{q}}^2)_{33}(M_\text{SUSY})$ | soft-breaking 3rd generation left-handed squark mass parameters | `EXTPAR[43]` | `mq33IN` $(m_{\tilde{u}}^2)_{11}(M_\text{SUSY})$ | soft-breaking 1st generation right-handed up-type squark mass parameters | `EXTPAR[44]` | `mu11IN` $(m_{\tilde{u}}^2)_{22}(M_\text{SUSY})$ | soft-breaking 2nd generation right-handed up-type squark mass parameters | `EXTPAR[45]` | `mu22IN` $(m_{\tilde{u}}^2)_{33}(M_\text{SUSY})$ | soft-breaking 3rd generation right-handed up-type squark mass parameters | `EXTPAR[46]` | `mu33IN` $(m_{\tilde{d}}^2)_{11}(M_\text{SUSY})$ | soft-breaking 1st generation right-handed down-type squark mass parameters | `EXTPAR[47]` | `md11IN` $(m_{\tilde{d}}^2)_{22}(M_\text{SUSY})$ | soft-breaking 2nd generation right-handed down-type squark mass parameters | `EXTPAR[48]` | `md22IN` $(m_{\tilde{d}}^2)_{33}(M_\text{SUSY})$ | soft-breaking 3rd generation right-handed down-type squark mass parameters | `EXTPAR[49]` | `md33IN` $M_\text{low}$ | scale where the SM(5) is matched to the MSSM | `EXTPAR[100]` | `Mlow` $\tan\beta(M_Z)$ | $\tan\beta(M_Z)=v_u(M_Z)/v_d(M_Z)$ | `MINPAR[3]` | `TanBeta`

All MSSM parameters, except for $\tan\beta$, are defined in the $\overline{\text{DR}}$ scheme at the scale $M_{\text{SUSY}}$. $\tan\beta$ is defined in the $\overline{\text{DR}}$ scheme at the scale $M_Z$.

Running the NUHMSSMNoFVHimalaya

We recommend to run NUHMSSMNoFVHimalaya with the following configuration flags: In an SLHA input file we recommend to use:

~~~~~~~~~~~~~~~~~~~~~~~{.txt} Block FlexibleSUSY 0 1.0e-05 # precision goal 1 0 # max. iterations (0 = automatic) 2 0 # algorithm (0 = all, 1 = two_scale, 2 = semi_analytic) 3 0 # calculate SM pole masses 4 3 # pole mass loop order 5 3 # EWSB loop order 6 3 # beta-functions loop order 7 2 # threshold corrections loop order 8 1 # Higgs 2-loop corrections O(alpha_t alpha_s) 9 1 # Higgs 2-loop corrections O(alpha_b alpha_s) 10 1 # Higgs 2-loop corrections O(alpha_t^2 + alpha_t alpha_b + alpha_b^2) 11 1 # Higgs 2-loop corrections O(alpha_tau^2) 12 0 # force output 13 1 # Top pole mass QCD corrections (0 = 1L, 1 = 2L, 2 = 3L) 14 1.0e-11 # beta-function zero threshold 15 0 # calculate observables (a_muon, ...) 16 0 # force positive majorana masses 17 0 # pole mass renormalization scale (0 = SUSY scale) 18 0 # pole mass renormalization scale in the EFT (0 = min(SUSY scale, Mt)) 19 0 # EFT matching scale (0 = SUSY scale) 20 2 # EFT loop order for upwards matching 21 1 # EFT loop order for downwards matching 22 0 # EFT index of SM-like Higgs in the BSM model 23 1 # calculate BSM pole masses 24 122111221 # individual threshold correction loop orders 25 0 # ren. scheme for Higgs 3L corrections (0 = DR, 1 = MDR) 26 1 # Higgs 3-loop corrections O(alpha_t alpha_s^2) 27 1 # Higgs 3-loop corrections O(alpha_b alpha_s^2) 28 1 # Higgs 3-loop corrections O(alpha_t^2 alpha_s) 29 1 # Higgs 3-loop corrections O(alpha_t^3) 30 1 # Higgs 4-loop corrections O(alpha_t alpha_s^3) ~~~~~~~~~~~~~~~~~~~~~~~

In the Mathematica interface we recommend to use:

~~~~~~~~~~~~~~~~~~~~~~~{.m} handle = FSNUHMSSMNoFVHimalayaOpenHandle[ fsSettings -> { precisionGoal -> 1.*^-5, (* FlexibleSUSY[0] *) maxIterations -> 0, (* FlexibleSUSY[1] *) solver -> 0, (* FlexibleSUSY[2] *) calculateStandardModelMasses -> 0, (* FlexibleSUSY[3] *) poleMassLoopOrder -> 3, (* FlexibleSUSY[4] *) ewsbLoopOrder -> 3, (* FlexibleSUSY[5] *) betaFunctionLoopOrder -> 3, (* FlexibleSUSY[6] *) thresholdCorrectionsLoopOrder -> 2,(* FlexibleSUSY[7] *) higgs2loopCorrectionAtAs -> 1, (* FlexibleSUSY[8] *) higgs2loopCorrectionAbAs -> 1, (* FlexibleSUSY[9] *) higgs2loopCorrectionAtAt -> 1, (* FlexibleSUSY[10] *) higgs2loopCorrectionAtauAtau -> 1, (* FlexibleSUSY[11] *) forceOutput -> 0, (* FlexibleSUSY[12] *) topPoleQCDCorrections -> 1, (* FlexibleSUSY[13] *) betaZeroThreshold -> 1.*^-11, (* FlexibleSUSY[14] *) forcePositiveMasses -> 0, (* FlexibleSUSY[16] *) poleMassScale -> 0, (* FlexibleSUSY[17] *) eftPoleMassScale -> 0, (* FlexibleSUSY[18] *) eftMatchingScale -> 0, (* FlexibleSUSY[19] *) eftMatchingLoopOrderUp -> 2, (* FlexibleSUSY[20] *) eftMatchingLoopOrderDown -> 1, (* FlexibleSUSY[21] *) eftHiggsIndex -> 0, (* FlexibleSUSY[22] *) calculateBSMMasses -> 1, (* FlexibleSUSY[23] *) thresholdCorrections -> 122111221, (* FlexibleSUSY[24] *) higgs3loopCorrectionRenScheme -> 0,(* FlexibleSUSY[25] *) higgs3loopCorrectionAtAsAs -> 1, (* FlexibleSUSY[26] *) higgs3loopCorrectionAbAsAs -> 1, (* FlexibleSUSY[27] *) higgs3loopCorrectionAtAtAs -> 1, (* FlexibleSUSY[28] *) higgs3loopCorrectionAtAtAt -> 1, (* FlexibleSUSY[29] *) higgs4loopCorrectionAtAsAsAs -> 1, (* FlexibleSUSY[30] *) parameterOutputScale -> 0 (* MODSEL[12] *) }, ... ]; ~~~~~~~~~~~~~~~~~~~~~~~

Uncertainty estimate of the predicted Higgs pole mass

In the file model_files/NUHMSSMNoFVHimalaya/NUHMSSMNoFVHimalaya_uncertainty_estimate.m FlexibleSUSY provides the Mathematica function `CalcNUHMSSMNoFVHimalayaDMh[]`, which calculates the Higgs pole mass at the 3-loop level with NUHMSSMNoFVHimalaya and performs an uncertainty estimate of missing higher order corrections. Three sources of the theory uncertainty are taken into account:

  • _missing higher order contributions to the Higgs mass_: The Higgs pole mass is calculated at the SUSY scale, $M_\text{SUSY}$, as a function of the running MSSM $\overline{\text{DR}}$ parameters at full 1-loop level plus 2-loop corrections of $O((\alpha_t + \alpha_b)\alpha_s + (\alpha_t + \alpha_b)^2 + \alpha_\tau^2)$ plus 3-loop corrections of $O((\alpha_t + \alpha_b)\alpha_s^2)$. The missing contributions are estimated by varying the scale within the interval $[M_{\text{SUSY}}/2, 2 M_{\text{SUSY}}]$.
  • _missing higher order contributions to the strong gauge coupling_: The running MSSM $\overline{\text{DR}}$ strong gauge coupling $g_3(M_Z)$ is calculated at the full 1-loop level plus 2-loop contributions of $O(\alpha_s^2 + (\alpha_t + \alpha_b)\alpha_s)$.

If the Higgs mass is calculated at the 3-loop level, then missing 4-loop strong corrections to $M_h$ are estimated by switching on/off the 2-loop contributions to $g_3(M_Z)$.

  • _missing higher order contributions to the top Yukawa coupling_: The running MSSM $\overline{\text{DR}}$ Yukawa coupling, $y_t(M_Z)$, is calculated at the full 1-loop level plus 2-loop contributions of $O(\alpha_s^2)$.

If the Higgs mass is calculated at the 2-loop level, then missing 3-loop top Yukawa-type corrections to $M_h$ are estimated by switching on/off the 2-loop contributions to $y_t(M_Z)$.

If the Higgs mass is calculated at the 3-loop level, then missing 4-loop top Yukawa-type corrections can currently not be estimated by switching on/off potential 3-loop contributions to $y_t(M_Z)$, because the latter are currently unknown.

The following code snippet illustrates the calculation of the Higgs pole mass at the 3-loop level with NUHMSSMNoFVHimalaya as a function of the SUSY scale (red solid line), together with the estimated uncertainty (grey band).

Get["models/NUHMSSMNoFVHimalaya/NUHMSSMNoFVHimalaya_librarylink.m"];
Get["model_files/NUHMSSMNoFVHimalaya/NUHMSSMNoFVHimalaya_uncertainty_estimate.m"];

settings = {
    precisionGoal -> 1.*^-5,
    maxIterations -> 1000,
    betaFunctionLoopOrder -> 3,
    poleMassLoopOrder -> 3,
    ewsbLoopOrder -> 3,
    thresholdCorrectionsLoopOrder -> 2,
    thresholdCorrections -> 122111121
};

smpars = {
    alphaEmMZ -> 1/127.916, (* SMINPUTS[1] *)
    GF -> 1.166378700*^-5,  (* SMINPUTS[2] *)
    alphaSMZ -> 0.1184,     (* SMINPUTS[3] *)
    MZ -> 91.1876,          (* SMINPUTS[4] *)
    mbmb -> 4.18,           (* SMINPUTS[5] *)
    Mt -> 173.34,           (* SMINPUTS[6] *)
    Mtau -> 1.77699,        (* SMINPUTS[7] *)
    Mv3 -> 0,               (* SMINPUTS[8] *)
    MW -> 80.385,           (* SMINPUTS[9] *)
    Me -> 0.000510998902,   (* SMINPUTS[11] *)
    Mv1 -> 0,               (* SMINPUTS[12] *)
    Mm -> 0.1056583715,     (* SMINPUTS[13] *)
    Mv2 -> 0,               (* SMINPUTS[14] *)
    md2GeV -> 0.00475,      (* SMINPUTS[21] *)
    mu2GeV -> 0.0024,       (* SMINPUTS[22] *)
    ms2GeV -> 0.104,        (* SMINPUTS[23] *)
    mcmc -> 1.27,           (* SMINPUTS[24] *)
    CKMTheta12 -> 0,
    CKMTheta13 -> 0,
    CKMTheta23 -> 0,
    CKMDelta -> 0,
    PMNSTheta12 -> 0,
    PMNSTheta13 -> 0,
    PMNSTheta23 -> 0,
    PMNSDelta -> 0,
    PMNSAlpha1 -> 0,
    PMNSAlpha2 -> 0,
    alphaEm0 -> 1/137.035999074,
    Mh -> 125.09
};

NUHMSSMNoFVHimalayaCalcMh[MS_, TB_, Xtt_] :=
    CalcNUHMSSMNoFVHimalayaDMh[
        fsSettings -> settings,
        fsSMParameters -> smpars,
        fsModelParameters -> {
            TanBeta -> TB,
            Qin -> MS,
            M1 -> MS,
            M2 -> MS,
            M3 -> MS,
            AtIN -> MS/TB + Xtt MS,
            AbIN -> MS TB,
            AtauIN -> MS TB,
            AcIN -> MS/TB,
            AsIN -> MS TB,
            AmuonIN -> MS TB,
            AuIN -> MS/TB,
            AdIN -> MS TB,
            AeIN -> MS TB,
            MuIN -> MS,
            mA2IN -> MS^2,
            ml11IN -> MS,
            ml22IN -> MS,
            ml33IN -> MS,
            me11IN -> MS,
            me22IN -> MS,
            me33IN -> MS,
            mq11IN -> MS,
            mq22IN -> MS,
            mq33IN -> MS,
            mu11IN -> MS,
            mu22IN -> MS,
            mu33IN -> MS,
            md11IN -> MS,
            md22IN -> MS,
            md33IN -> MS
        }
   ];

LinearRange[start_, stop_, steps_] :=
    Range[start, stop, (stop - start)/steps];

Xtt = -2;
TB  = 5;

data = ParallelMap[
    { N[#], Sequence @@ NUHMSSMNoFVHimalayaCalcMh[#, TB, Xtt] }&,
    LinearRange[500, 10^4, 100]
];

MhMin[{MS_, Mh_, DMh_}]  := {MS, Mh - DMh};
MhMax[{MS_, Mh_, DMh_}]  := {MS, Mh + DMh};
MhBest[{MS_, Mh_, DMh_}] := {MS, Mh};

dataMhMin  = MhMin  /@ data;
dataMhMax  = MhMax  /@ data;
dataMhBest = MhBest /@ data;

plot2 = ListLinePlot[dataMhBest,
                     PlotStyle -> {Red, Thick}];

plot1 = ListLinePlot[{dataMhMax, dataMhMin},
                     PlotStyle -> LightGray,
                     Filling -> {1 -> {{2}, LightGray}},
                     PlotRange -> All];

plot = Show[{plot1, plot2},
            BaseStyle -> {FontSize -> 16, FontFamily -> "Helvetica"},
            PlotLabel -> Style["\*SubscriptBox[X, t] = -2 \*SubscriptBox[M, S], tan\[Beta] = 5"],
            PlotRange -> Automatic,
            Axes -> False, Frame -> True,
            FrameLabel -> {Style["\*SubscriptBox[M, S] / GeV"],
                           Style["\*SubscriptBox[M, h] / GeV"]}];

Export["NUHMSSMNoFVHimalaya_Mh_MS.png", plot, ImageSize -> 600];

When this script is executed, the following figure is produced:

NUHMSSMNoFVHimalaya_Mh_MS.png